Days-16 on Internet of Things with the NanoESP

Day 24: Gift box

Sat, 24 Dec 2016 00:01:53 +0100

With the last test in this Advent, we get really Christmasy. We’re building a reusable gift box with which you can delight your relatives. Every time someone opens the present, the contents are lit up in an individual colour, and a Christmas sound plays.

Behind today’s door is a retro-reflective sensor. This is actually two components, an IR transmitter diode and a phototransistor. It’s not very easy to see which way the elements have to be connected in terms of polarity. For this reason, it’s best if you connect the photoelectric sensor with the connection cables according to the example shown. Then you won’t be able to switch the polarity as easily.

Day 23: MQTT Climate

Fri, 23 Dec 2016 00:01:49 +0100

Behind the door for today is a battery clip for a 9 V block, with which you can make the entire system moveable. An alternative to a battery is a power bank (a rechargeable battery pack, normally for mobile phones). You can see in today’s layout picture how to connect a 9 V battery correctly.

This is how you can connect a 9 V battery to today's layout

Climate data should be captured again today. But this time they are published through the MQTT broker and are thus accessible worldwide. The data could thus be called up via a plug-in and stored in a database.

Day 22: MQTT Cheerlights

Thu, 22 Dec 2016 00:01:31 +0100

Today’s trial is about MQTT and a global project that was presented last year: the Cheerlights Project by Hans Schaaler. For everyone who doesn’t know the project: It’s about globally networked coloured lights that can be simultaneously controlled through Twitter commands. Another version of this project was part of last year’s Advent calendar. This year we have the version with MQTT and expanded functions.

Behind today’s door is a 1-kohm resistor. The layout consists of the RGB LED with series resistors and a button.

Day 21: House automation

Wed, 21 Dec 2016 00:01:34 +0100

In today’s test, we’ll illuminate the characteristics and possibilities of MQTT in more detail by creating a practical scenario. In the example, there is a building with two rooms, each of which has a light switch, a light and an alarm sensor. The light switch switches the light of the respective room on or off. The alarm sensors activate a building-wide alarm.

Normally, seven different devices would be used here, which are all connected to each other through an MQTT broker. But since we probably have only one NanoESP, this will simulate all devices. For this reason, today’s layout looks somewhat complicated. The LED D3 is used today as the second light. Therefore, today it won’t show you whether you’re connected to the WLAN. The tilt sensors are used on the extension cables as alarm sensors. A person could, for example, attach them to doors or windows so that they trigger an alarm if the entry opens. Behind today’s door is the second sensor.

Day 20: MQTT (Message Queue Telemetry Transport)

Tue, 20 Dec 2016 00:01:05 +0100

For the last days of this Advent, you’ll now become familiar with a subject that plays a large role in the realm of the IoT. We’re dealing with the messaging protocol MQTT, which was specially developed for the communication from machine to machine (M2M). The protocol is thus so brilliant because e.g. control data, measurement data or texts can be exchanged very easily and compactly. The overhead (data that’s transferred alongside the actual user data) is much lower than with HTTP and can be processed readily even by embedded devices, meaning microcontrollers like our NanoESP. At the same time, the controller doesn’t constantly have to establish a connection and query whether there’s been a change; instead, the connection is continually maintained and the client automatically gives information about changes.

Day 19: Configuration page for the NanoESP

Mon, 19 Dec 2016 00:01:07 +0100

Behind today’s door is another cable. With the two cables it’s possible, for example, to place the RGB LED apart from the board. We’ll need the RGB LED today because the test is about a website with which you can adjust its colours. But that’s not the main aspect: To make the configuration of the NanoESP board especially easy not just for programmers, there is a configuration page through which the WLAN data of the module can be adjusted. But first to the set-up. You see it in the following picture.

Day 18: Weather monitoring

Sun, 18 Dec 2016 00:01:35 +0100

Behind today’s door is a very special component, namely a humidity sensor. Together with the phototransistor and the NTC, it creates a weather station for at-home use. The following layout is necessary for this purpose:

The layout with all sensors (resistors 1 kohm)

Today’s layout is a bit fiddly. Especially at the point where the potentiometer on the right of the image sits, it touches the NanoESP. But that’s not really a problem as long as the contact on the left of the image is plugged firmly into the board.

Day 17: Wake Up Light

Sat, 17 Dec 2016 00:01:56 +0100

Today’s project deals with a well-known lamp from Phillips, the Wake Up Light. This is an alarm clock that, instead of making a loud noise, slowly increases the brightness. This creates a type of sunrise, and one wakes up in a natural manner.

Behind today’s door is another potentiometer, which is important for tomorrow’s test. The following layout is required today:

The RGB LED with series resistors

The sketch: A16_P17_WakeUpLight.ino

/*
 TCP-Server: Wakeup light
 Change SSID and PASSWORD.
 RGB-Led (common cathode) on Pins 3,5,6
*/

#include <NanoESP.h>
#include <NanoESP_HTTP.h>
#include <SoftwareSerial.h>
#include "Websites.h"

#include <math.h>
#include <Time.h>

#define SSID "YourSSID"
#define PASSWORD "YourPassword"

#define LED_WLAN 13

#define RED 3
#define GREEN 5
#define BLUE 6
#define GND 4

#define BUTTON 7

NanoESP nanoesp = NanoESP();
NanoESP_HTTP http = NanoESP_HTTP(nanoesp);

//String timeServerIP = ; // time.nist.gov NTP server address
String ntpServerName = "195.145.119.188";//"time.nist.gov";
const int NTP_PACKET_SIZE = 48; // NTP time stamp is in the first 48 bytes of the message
byte packetBuffer[NTP_PACKET_SIZE]; //buffer to hold incoming and outgoing packets

int alarmHour = 0, alarmMinute = 2;
bool alarm;
byte cRed = 0, cBlue = 0, cGreen = 0;

unsigned long previousMillis = 0; // will store last time a msg was send
unsigned long interval = 78; //

void setup() {
 Serial.begin(19200);
 nanoesp.init();

 pinMode(RED, OUTPUT);
 pinMode(GREEN, OUTPUT);
 pinMode(BLUE, OUTPUT);

 pinMode(GND, OUTPUT);
 digitalWrite(GND, LOW);

 pinMode(BUTTON, INPUT);

 //Only Station Mode for TimeSync
 nanoesp.configWifiMode(STATION);
 //delay(1000);

 // Wait till Connected to WiFi
 if (nanoesp.wifiConnected())digitalWrite(LED_WLAN, HIGH); else Serial.println(F("Error WLAN Connect"));

 //Start TCP Server
 if (nanoesp.startTcpServer(80)) Serial.println(F("TCP Server Activ")); else Serial.println(F("TCP Server Error"));

 //Print IP in Terminal
 Serial.println(nanoesp.getIp());

 setSyncProvider(getNtpTime);
 Show_Time();
}


time_t getNtpTime() {
 //convert to time_t , Paramter: connectionId, ServerAdress, Timezone
 return (time_t)getNTPpacket(4, ntpServerName, 2);
}

void loop() {
 String method, ressource, parameter;
 int id ;

 if (http.recvRequest(id, method, ressource, parameter)) {

 Serial.println("New Request from id :" + String(id) + ", method: " + method + ", ressource: " + ressource + " parameter: " + parameter);

 if (ressource == "/") {
 http.sendFromFlash(id, index, sizeof(index));
 nanoesp.closeConnection(id);
 }

 if (ressource == "/settimer") {
 if (parameter != "") {
 //timer=02%3A03&
 String sHour = parameter.substring(parameter.indexOf('=') + 1, parameter.indexOf('%'));
 String sMin = parameter.substring(parameter.indexOf('A') + 1, parameter.indexOf('&'));

 String sDuration = parameter.substring(parameter.indexOf('&') + 1);
 sDuration = sDuration.substring(sDuration.indexOf('=') + 1, sDuration.indexOf('&'));

 alarmHour = sHour.toInt();
 alarmMinute = sMin.toInt();
 int iDuration = sDuration.toInt();
 interval *= iDuration;

 Serial.println("Timer: " + String(alarmHour) + ":" + String(alarmMinute) + " Duartion: " + String (iDuration) );
 Show_Time();

 }
 nanoesp.closeConnection(id);
 }


 if (ressource == "/turnoff") {
 alarm = false;
 cRed = 0; cBlue = 0; cGreen =0;
 analogWrite(RED,cRed); analogWrite(BLUE,cBlue);analogWrite(GREEN,cGreen);
 }

 else {
 http.sendFromFlash(id, error404, sizeof(error404));
 nanoesp.closeConnection(id);
 }
 }
 else {
 if (hour() == alarmHour) {
 if (minute() == alarmMinute) {
 if (!alarm) alarm = true;
 }
 }

 if (alarm) wakeUp();
 }
}

void MorningAlarm() {

 Serial.println("Alarm: - turn lights off");
}


void wakeUp() {
 if (millis() - previousMillis >= interval) {
 previousMillis = millis();
 if (cRed == 0) Show_Time();
 if (cRed < 255) {
 cRed++; analogWrite(RED, cRed );
 }
 else {
 if (cGreen < 255) {
 cGreen++;
 analogWrite(GREEN, cGreen);
 }
 else {
 if (cBlue < 255) {
 cBlue++;
 analogWrite(BLUE, cBlue );
 if (cBlue == 255) Show_Time();
 }
 }
 }
 }
}



// prepare an NTP request to the time server and send to the given
bool sendNTPpacket(int id, String address)
{
 // set all bytes in the buffer to 0
 memset(packetBuffer, 0, NTP_PACKET_SIZE);
 // Initialize values needed to form NTP request
 // (see URL above for details on the packets)
 packetBuffer[0] = 0b11100011; // LI, Version, Mode
 packetBuffer[1] = 0; // Stratum, or type of clock
 packetBuffer[2] = 6; // Polling Interval
 packetBuffer[3] = 0xEC; // Peer Clock Precision
 // 8 bytes of zero for Root Delay & Root Dispersion
 packetBuffer[12] = 49;
 packetBuffer[13] = 0x4E;
 packetBuffer[14] = 49;
 packetBuffer[15] = 52;
 //
 // if we need a cr/lf
 //
 packetBuffer[NTP_PACKET_SIZE ] = 0x0D;
 packetBuffer[NTP_PACKET_SIZE + 1] = 0x0A;
 // all NTP fields have been given values, now
 // you can send a packet requesting a timestamp:
 if ( nanoesp.sendRaw(id, packetBuffer, NTP_PACKET_SIZE)) return true;
 return false;
}

long getNTPpacket(int id, String address, int timeZone) {
 unsigned long secsSince1900;
 byte offset = 40;

 if (!nanoesp.newConnection(id, UDP, address, 123)) Serial.println ("no connection ntp server"); //NTP requests are to port 123
 delay(100);
 if (!sendNTPpacket(id, address)) {
 Serial.println("No time request send");
 return 0;
 }
 nanoesp.setTimeout(2000);
 if (nanoesp.find("+IPD,")) {
 int vid = nanoesp.parseInt();
 nanoesp.find(",");
 int len = nanoesp.parseInt();
 //Serial.println(String(len));
 byte buffer[len];

 nanoesp.find(":");
 nanoesp.readBytes(buffer, 48);

// for (int i = 0; i <= NTP_PACKET_SIZE; i++) {
// Serial.print(buffer[i], HEX);
// }

 // convert four bytes starting at location 40 to a long integer
 secsSince1900 = (unsigned long)buffer[offset + 0] << 24;
 secsSince1900 |= (unsigned long)buffer[offset + 1] << 16;
 secsSince1900 |= (unsigned long)buffer[offset + 2] << 8;
 secsSince1900 |= (unsigned long)buffer[offset + 3];

 nanoesp.find("OK\r\n");
 nanoesp.closeConnection(id);

 // return secsSince1900 + timeZone * SECS_PER_HOUR; // NTP Date
 return secsSince1900 - 2208988800UL + timeZone * SECS_PER_HOUR; // UNIX Date
 }
 else {
 Serial.println("no time recieved");
 nanoesp.closeConnection(id);
 return 0;
 }
}

void Show_Time()
{
 String shour, sminute, ssecond;

 Serial.print("Date: ");
 Serial.print(day());
 Serial.print(".");
 Serial.print(month());
 Serial.print(".");
 Serial.println(year());


 if (hour() <= 9) shour = "0" + String(hour()); else shour = String(hour()); // adjust for 0-9
 if (minute() <= 9) sminute = "0" + String(minute()); else sminute = String(minute());
 if (second() <= 9) ssecond = "0" + String(second()); else ssecond = String(second());
 Serial.println( "Time: " + shour + ":" + sminute + ":" + ssecond );
}

(The former Arduino Create embed is no longer available; the code is taken from the download of all sketches.)

Day 16: A web server piano

Fri, 16 Dec 2016 00:01:54 +0100

Behind today’s door is a piezo sound transducer. It’s possible to generate sounds with it, which will become clear in today’s test. Today you’re building a type of piano that can be used via a website. See the following picture for the layout:

The correct connection of the piezo sound transducer

The sketch: A16_P16_WebserverPiano.ino

/*
 TCP-Server Piano
 Change SSID and PASSWORD.
*/

#include <NanoESP.h>
#include <NanoESP_HTTP.h> //special library for http-connection
#include <SoftwareSerial.h>
#include "Websites.h" //websites in a special file as progmem

#define SSID "YourSSID"
#define PASSWORD "YourPassword"

#define LED_WLAN 13

NanoESP nanoesp = NanoESP();
NanoESP_HTTP http = NanoESP_HTTP(nanoesp);

void setup() {
 Serial.begin(19200);
 nanoesp.init();

 //! Only if you want to change the ACCESPOINT configuration
 //nanoesp.configWifi(ACCESSPOINT, "NanoESP", "");

 //! Only if you use a new Network
 // nanoesp.configWifi(DUAL, SSID, PASSWORD);

 //Dual Mode
 nanoesp.configWifiMode(DUAL);
 //delay(1000);

 // Wait till Connected to WiFi
 if (nanoesp.wifiConnected())digitalWrite(LED_WLAN, HIGH); else Serial.println(F("Error WLAN Connect"));

 //Start TCP Server
 if (nanoesp.startTcpServer(80)) Serial.println(F("TCP Server Activ")); else Serial.println(F("TCP Server Error"));

 //Print IP in Terminal
 Serial.println(nanoesp.getIp());
}

void loop() {
 String method, ressource, parameter;
 int id;

 if (http.recvRequest(id, method, ressource, parameter)) { //Incoming request, parameters by reference

 Serial.println("New Request from id :" + String(id) + ", method: " + method + ", ressource: " + ressource + " parameter: " + parameter);

 if (ressource == "/") {
 http.sendFromFlash(id, index, sizeof(index));
 nanoesp.closeConnection(id);
 }

 else if (ressource == "/dataonly") { //only data is recieved on this url, no need to send a website
 nanoesp.closeConnection(id);
 }

 else {
 http.sendFromFlash(id, error404, sizeof(error404));
 nanoesp.closeConnection(id);
 }

 if (parameter != "") //the request included parameters
 {
 String strTone;
 if (method == GET) strTone = parameter.substring(6); else strTone = parameter.substring(5); //get note values
 noTone(8);
 tone(8, strTone.toInt(), 200); //play note for 200ms
 }

 }
}

(The former Arduino Create embed is no longer available; the code is taken from the download of all sketches.)

Day 15: A web server

Thu, 15 Dec 2016 00:01:28 +0100

Since the Blynk platform was the central point of our projects over the last few days, now we’re coming to a totally new subject: the NanoESP as web server. You’ve already gotten a first impression of it in the test for the first day. In the coming days, we’ll see what all else is possible.

Behind today’s door is a special two-core cable with which you can connect e.g. even LEDs or sensors outside the board. For today’s test, however, no hardware layout is necessary at all. You only need the programme and a browser.

Day 14: Long-term temperature measurement

Wed, 14 Dec 2016 00:01:14 +0100

Behind today’s door is an NTC sensor (negative temperature coefficient thermistor). Its conductivity changes depending on the temperature. You’ll use the sensor today to undertake a long-term measurement of the temperature. As a small bonus, you can select a time at which you get a summary by email.

For today’s layout, in addition to the NTC, you’ll also need the potentiometer and a 1-kohm resistor. You can make a fine adjustment of the temperature with the potentiometer.

Day 13: Alarm system with push messages

Tue, 13 Dec 2016 00:01:56 +0100

Today’s project deals with a simple silent alarm system with password input for resetting the alarm. So that you get anything at all from the alarm, the board sends a push message to your smartphone. We’ll set the tilt sensor that’s behind today’s door as a motion detector. It can give information about vibrations and thus inform you if someone tips the NanoESP board.

Layout with tilt sensor

The sketch: A16_P13_Blynk9_PushAlarm.ino

/*
 Blnky9: PushAlarm
 Change ssid, password and token
*/

char ssid[] = "YourSSID";
char password[] = "YourPassword";
char token[] = "YourToken";

String passwordAlarm = "password";
String alarmMsg = "Alarm! Someone touched the NanoESP!";

#define BLYNK_DEBUG
#define BLYNK_PRINT Serial // Comment this out to disable prints and save space
#include <ESP8266_SoftSer.h>
#include <BlynkSimpleShieldEsp8266_SoftSer.h>
#include <SimpleTimer.h>

// Set ESP8266 Serial object
#include <SoftwareSerial.h>
SoftwareSerial EspSerial(11, 12); // RX, TX

ESP8266 wifi(EspSerial);
SimpleTimer timer;

WidgetTerminal terminal(V1);

boolean alarm = false;

void setup()
{
 // Set console baud rate
 Serial.begin(19200);
 EspSerial.begin(19200);

 Blynk.begin(token, wifi, ssid, password);

 //push msg
 Blynk.notify("Alarm active");

 pinMode(2, INPUT_PULLUP);

 //timer for blinking led on alarm
 timer.setInterval(1000L, blinkAlarm);
}

void loop()
{
 Blynk.run();
 if (alarm) timer.run(); else digitalWrite(13, LOW); //blink if alarm active

 if (digitalRead(2)) { //read tilt sensor
 if (!alarm) {
 alarm = true;

 Blynk.notify(alarmMsg); //push msg on alarm

 terminal.println(F("Alarm! Type in Password:"));
 terminal.flush();
 }
 }
}


BLYNK_CONNECTED() {
 Blynk.syncAll();

 terminal.println(F("Blynk v" BLYNK_VERSION ": Device started"));
 terminal.println("-------------");
 terminal.flush();
}


BLYNK_WRITE(V1) //Terminal
{
 //type in password on alarm
 if (alarm) {

 String passInput = param.asStr();

 if (passwordAlarm == passInput) {
 alarm = false;
 terminal.println(F("Alarm deaktivated"));
 terminal.flush();

 }
 else {
 terminal.println(F("Wrong password!"));
 terminal.flush();
 }
 }
}


//timer function for blinking led on alarm
void blinkAlarm()
{
 digitalWrite(13, !digitalRead(13));
}

(The former Arduino Create embed is no longer available; the code is taken from the download of all sketches.)

Day 12: Light monitor

Mon, 12 Dec 2016 00:01:46 +0100

Behind today’s door, you’ll find a phototransistor. This is a sensor with which the brightness can be measured. You’ll do that today, but in addition to simple measurement, the project also sounds an alarm as soon as limit values that you’ve pre-set in the app are exceeded. So that everything will function, you have to connect the sensor with a voltage divider circuit at Pin A0, as shown in the picture below. Pay attention to the correct polarity of the phototransistor (short leg to VCC). It does also work the other way round, but not nearly as sensitively.

Day 11: Day- and nightlight

Sun, 11 Dec 2016 00:01:57 +0100

Behind today’s door is a 10-kohm resistor, but we don’t need it yet today. Instead, the set-up from yesterday’s test works today as well. In this project, you’ll build a day-night lamp that changes colours at specific times. Thus you can have a bright light shining during the day, while at night only a dim red serves as emergency lighting for a bit of orientation.

The layout from Day 10

The sketch: A16_P11_Blynk7_DayNight.ino

/*
Blynk 7: DayNight
Change ssid, password and token
*/

char ssid[] = "YourSSID";
char password[] = "YourPassword";
char token[] = "YourToken";

#define BLYNK_DEBUG
#define BLYNK_PRINT Serial // Comment this out to disable prints and save space
#include <ESP8266_SoftSer.h>
#include <BlynkSimpleShieldEsp8266_SoftSer.h>

// Set ESP8266 Serial object
#include <SoftwareSerial.h>
SoftwareSerial EspSerial(11, 12); // RX, TX

ESP8266 wifi(EspSerial);

boolean isDay;

void setup()
{
 // Set console baud rate
 Serial.begin(19200);
 EspSerial.begin(19200);

 Blynk.begin(token, wifi, ssid, password);
}

void loop()
{
 //all events are handled by functions below
 Blynk.run();
}


BLYNK_CONNECTED() {
 //Sync all states when reconnected
 Blynk.syncAll();
}


BLYNK_WRITE(V1) //DayTimer
{
 if (param.asInt()== 1){
 Blynk.virtualWrite(V0,1);
 Blynk.virtualWrite(V7,0);
 isDay = true;
 Blynk.syncVirtual(V3);
 }
}

BLYNK_WRITE(V4) //NightTimer
{
 if (param.asInt()== 1){
 Blynk.virtualWrite(V0,0);
 Blynk.virtualWrite(V7,1);
 isDay = false;
 Blynk.syncVirtual(V8);
 }
}

BLYNK_WRITE(V0) //Day
{
 if(param.asInt()==1)
 {
 Blynk.virtualWrite(V7,0);
 isDay = true;
 Blynk.syncVirtual(V3);
 }
}

BLYNK_WRITE(V7){ //Night

if(param.asInt()==1)
 {
 Blynk.virtualWrite(V0,0);
 isDay = false;
 Blynk.syncVirtual(V8);
 }
}

BLYNK_WRITE(V3) // change color Day
{
 if (isDay){
 analogWrite(3, param[0].asInt()); // getting first value
 analogWrite(5, param[1].asInt()); // getting second value
 analogWrite(6, param[2].asInt()); // getting N value
 }
}

BLYNK_WRITE(V8) // change color Night
{
 if (!isDay){
 analogWrite(3, param[0].asInt()); // getting first value
 analogWrite(5, param[1].asInt()); // getting second value
 analogWrite(6, param[2].asInt()); // getting N value
 }
}

(The former Arduino Create embed is no longer available; the code is taken from the download of all sketches.)

Day 10: Colour mixing

Sat, 10 Dec 2016 00:01:27 +0100

Behind today’s door is the reason for the many 1-kohm resistors. Namely, what you find there is a so-called RGB LED RGB stands for red-greenblue, since this LED is actually three LEDs that can be connected through a common cathode. By varying the brightness of the individual LEDs using PWM, you can generate almost every colour conceivable.

You can see the layout of today’s circuit in the following figure. Note that the somewhat longer leg (the cathode) must be plugged into the GND contact strip.

Day 9: Brightness of the real LED

Fri, 09 Dec 2016 00:01:46 +0100

Behind today’s door is another 1-kohm resistor. But today you don’t have to change anything in the hardware layout from yesterday. Only a small detail changes on the interface.

The layout from yesterday

You don’t have to re-upload the programme because you’re simply manually adjusting the interface from yesterday. If you’d like to load the interface in the app anyway for safety’s sake, you’ll find the QR code here as usual. But then you also have to re-enter the token in your programme.

Day 8: Virtual LEDs

Thu, 08 Dec 2016 00:01:15 +0100

In the test for the sixth day, you saw how a push button on the hardware side can be mapped on a button in the app. However, another widget, namely the LED widget, is much simpler for this instance. In today’s test, you’ll see how to use it properly and what options it offers.

Behind today’s door is another 1-kohm resistor that is important for later tests. Today the circuit from yesterday is expanded by a button.

Day 7: Analogue write

Wed, 07 Dec 2016 00:01:18 +0100

Behind today’s door is a potentiometer. You can use it to transfer analogue messages to the Blynk app. To do this, you need to build the circuit according to the picture.

The potentiometer uses the lower wire for the connection to A0

Things can get a bit tight when constructing with the MicroUSB cable. So that everything connects, you first have to disconnect the board from the cable and place the jumpers to be as flat as possible. You also need to be aware that this time the VCC is not applied to the track at the bottom of the image; instead, the track is intended for the connection at Pin A0.

Day 6: The hardware button

Tue, 06 Dec 2016 00:01:21 +0100

In yesterday’s test, you realised a simple control of an LED using the Blynk app. Today you’ll see that the control works in both directions. The push-button switch behind today’s door really comes in handy for this purpose. With it, you can expand yesterday’s circuit as follows:

The new layout with push-button switch at D7

You can scan the interface for today here:

Day 5: Blynk

Mon, 05 Dec 2016 00:01:46 +0100

You already established a first connection from the board to the Internet yesterday. In the coming days, this connection should be used effectively. So we’re looking at the online platform Blynk, through which short commands, measurement data or messages can be exchanged between the NanoESP board and your smartphone.

Communication with the Blynk Server

Blynk enables the simple control of various IoT boards, e.g. the Raspberry Pi or our NanoESP, using an app. You can put the graphic interface together completely on your own, and programming is also extremely simple. As if that weren’t enough, you can even control the board from anywhere in the world. So it’s totally within the sense of the Internet of Things.

Day 4: Setting up Internet connection

Sun, 04 Dec 2016 00:01:49 +0100

Behind today’s door is a 1-kohm resistor. We’re not going to do much with it today, but tomorrow it becomes important. In today’s test, we want to set up an initial connection to your home WLAN network. For this purpose, you need, as you will on many days to come, to enter your WLAN data in the programme.

The Board pings the Goolge server

But first you need to download today’s programme. You can download it via the right button on the from the Arduino Create Iframe.

Day 3: The NanoESP in access point mode

Sat, 03 Dec 2016 00:01:18 +0100

Behind the third door is the jumper wire, which is important for many tests. To prepare for later tests, you can place the supply lines GND and VCC on the outermost lanes. You’ll thereby have better access to these important lines later.

The jumpers to GND and VCC

In the project for today, you now get around to changing something in a programme even on your own. The following sample programme serves as a basis:

Day 2: The Arduino IDE

Fri, 02 Dec 2016 00:01:47 +0100

This time there’s a breadboard behind the door. On it, you can quickly and easily assemble the hardware layouts of the Advent calendar. Since only the NanoESP is available so far, we’ll start with it.

NanoESP on a breadboard

It’s best if you plug the controller into the breadboard as shown in the picture. That way, the greatest space remains free for experiments; the WLAN module sticks out behind past the breadboard. The micro-USB cable then hangs between the contact sides and is only a minimal disruption. The board needs to be pressed in gently until it touches the contacts.

Tag 1: Das NanoESP-Board

Thu, 01 Dec 2016 00:01:19 +0100

It’s the first of December and thus time to open the first door. Behind it is arguably the most important element of the calendar: the NanoESP board. This Arduino-compatible controller with WLAN function is at the centre of the 24 tests.

The NanoESP Board

To s briefly, it can be said that the board is most likely a cross between a board similar to an Arduino Nano and a WLAN module with the name ESP8266. The communication between the two elements runs through a serial port generated via software, which is connected to Pins D11 and D12. You should thus avoid these pins with your own projects.

Library for NanoESP & Pretzel Board

Mon, 19 Sep 2016 12:25:19 +0200